// Name: Arduino Mega Midi Controller Mega side.
// Created: May 10,   2021
// Last Edited: Mar 26, 2022
// Author: Larason2
// Acknowledgements:   Bald Engineer, Amanda Ghassaei, jeffb42, GrumpyMike, John Main, Ghost, RIP Tutorial,   Arduino tutorials.
// Includes Midi Through, wiring for pistons, improved debounce.
 
//für Arduino Due und MIDIUSB-Bibliothek angepasst
 
#include "MIDIUSB.h"
 

 
//###############Diodenmatrix-Variablen##############################
//Amount of Rows and Columns
const int rows = 8;
const int cols = 8;
 
//Entprellen der Tasten
unsigned long Delay = 10; //in Millisekunden
unsigned long DelayMikro = 10; //in Mikrosekunden, 10 ging so recht und schlecht
 
//MIDI Kanal
int midichannel = 3; //das ergibt Kanal 4 für das 3. Manual
//####################################################################
 

 
//Setup   Key Data Arrays
byte keysA[rows][cols] = { {1, 1, 1, 1, 1, 1, 1, 1}, {1, 1, 1, 1, 1, 1, 1, 1}, {1, 1, 1, 1, 1, 1, 1, 1}, {1, 1, 1, 1, 1, 1, 1, 1},
  {1, 1, 1, 1, 1, 1, 1, 1}, {1, 1, 1, 1, 1, 1, 1, 1}, {1, 1, 1, 1, 1, 1, 1, 1}, {1, 1, 1, 1, 1, 1, 1, 1},
};
 
//Setup Key Press Arrays
byte lastA[rows][cols];
 

//deckungsgleich zum Tasten-Array die MIDI-Codes für NoteOn/Off
uint8_t keyToMidiMap[rows][cols] = { 36, 37, 38, 39, 40, 41, 42, 43,
                                     44, 45, 46, 47, 48, 49, 50, 51,
                                     52, 53, 54, 55, 56, 57, 58, 59,
                                     60, 61, 62, 63, 64, 65, 66, 67,
                                     68, 69, 70, 71, 72, 73, 74, 75,
                                     76, 77, 78, 79, 80, 81, 82, 83,
                                     84, 85, 86, 87, 88, 89, 90, 91,
                                     92, 93, 94, 95, 96, 97, 98, 99,
                                   };
 

 
//Entprellen der Tasten
unsigned long BounceAOn[rows][cols];
unsigned long BounceAOff[rows][cols];
 

//row-Pins
uint8_t rowpin[rows] = {22, 24, 26, 28, 30, 32, 34, 36};
 
//col-Pins
uint8_t colpin[cols] = {23, 25, 27, 29, 31, 33, 35, 37};
 

/** Funktionen für MIDI *****************************************************/
void noteOn(byte channel, byte pitch, byte velocity) {
  midiEventPacket_t noteOn = {0x09, 0x90 | channel, pitch, velocity};
  MidiUSB.sendMIDI(noteOn);
  delayMicroseconds(300);
  MidiUSB.flush();
}
 
void noteOff(byte channel, byte pitch, byte velocity) {
  midiEventPacket_t noteOff = {0x08, 0x80 | channel, pitch, velocity};
  MidiUSB.sendMIDI(noteOff);
  delayMicroseconds(300);
  MidiUSB.flush();
}
 
void sendControlChange (byte channel, byte controller, byte value) {
  midiEventPacket_t event = {0x0B, 0xB0 | channel, controller, value};
  MidiUSB.sendMIDI(event);
  MidiUSB.flush();
}
 
/****************************************************************************/
 

void setup() {
  
  for (int i = 0; i <= 7; i++) {
    pinMode(rowpin[i], INPUT);
    pinMode(colpin[i], INPUT);
  }
  
}
 
void loop() {
  
  for (int i = 0; i <= 7; i++) {
    pinMode(colpin[i], INPUT_PULLUP);
  }
 
  delayMicroseconds(DelayMikro);
 
  for (int i = 0; i <= 7; i++) {
    pinMode(rowpin[i], OUTPUT);
    digitalWrite(rowpin[i], LOW);
    delayMicroseconds(DelayMikro);
 
    for (int j = 0; j <= 7; j++) {
      keysA[i][j] = digitalRead(colpin[j]);
      delayMicroseconds(DelayMikro);
    }
 
    pinMode(rowpin[i], INPUT);
    delayMicroseconds(DelayMikro);
  }
 
  for (int i = 0; i <= 7; i++) {
    pinMode(colpin[i], INPUT);
  }
 
  delayMicroseconds(DelayMikro);
 

  //gedrückte Tasten als MIDI-Befehle senden
  for (int i = 0; i <= 7; i++) {
 
    for (int j = 0; j <= 7; j++) {
 
      if (keysA[i][j] == LOW && lastA[i][j] == HIGH && ((millis() - BounceAOn[i][j]) > Delay)) {
        noteOn(midichannel, keyToMidiMap[i][j], 127);
        lastA[i][j] = keysA[i][j];
        BounceAOff[i][j] = millis();
      }
      if (keysA[i][j] == HIGH && lastA[i][j] == LOW && ((millis() - BounceAOff[i][j]) > Delay)) {
        noteOff(midichannel, keyToMidiMap[i][j], 0);
        lastA[i][j] = keysA[i][j];
        BounceAOn[i][j] =   millis();
      }
    }
  }
}